home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / pc / LOGIC Apple II 5.25" Library - DOS Part 3 / DOS077A.dsk / ROMAN NUMBERS.bas < prev    next >
BASIC Source File  |  2012-02-16  |  2KB  |  51 lines
  1. 1  REM  PROGRAM STARTS AT LINE 800
  2. 2  REM  PROGRAM IS SET FOR PRINTER IN SLOT #1.  LINE 860 MUST BE CHANGED IF YOUR PRINTER IS IN ANOTHER SLOT
  3. 3  REM  PROGRAM WRITTEN BY NELSON GOTHIE BOX 42 BREEZEWOOD, PENNA., 15533 NOVEMBER 1979.  PHONE 814-735-4553
  4. 800  TEXT : HOME : VTAB 5: PRINT "THIS PROGRAM CONVERTS ARABIC NUMBERS TO ROMAN NUMERALS"
  5. 810  PRINT : PRINT "YOU MUST ENTER THE FIRST AND LAST NUMBERYOU WISH TO CONVERT.  TO GET JUST ONE   NUMBER ENTER IT AS FIRST AND LAST"
  6. 820  PRINT : PRINT "THE NUMBER CANNOT BE LARGER THAN 1999"
  7. 825  PRINT 
  8. 830  INPUT "ENTER THE SMALLER NUMBER ";SN
  9. 835  PRINT 
  10. 840  INPUT "ENTER THE LARGER NUMBER ";LN
  11. 850  PRINT : PRINT "DO YOU WISH A PRINT? Y/N": INPUT Q$
  12. 860  IF Q$ = "Y"  THEN  PR# 1
  13. 870  PRINT 
  14. 900  FOR Z = SN TO LN
  15. 910 X = Z
  16. 1010  IF X <1000  THEN 1100
  17. 1020 RN$ = "M":X = X -1000
  18. 1100  IF X <900  THEN 1150
  19. 1110 RN$ = RN$ +"CM"
  20. 1115 X = X -900
  21. 1150  IF X <500  THEN 1167
  22. 1160 RN$ = RN$ +"D":X = X -500
  23. 1167  IF X <400  THEN 1170
  24. 1168 RN$ = RN$ +"CD":X = X -400
  25. 1170 Y =  INT(X/100)
  26. 1175  IF Y <1  THEN 1200
  27. 1180  FOR I = 1 TO Y
  28. 1190 RN$ = RN$ +"C":X = X -100: NEXT I
  29. 1200  IF X <90  THEN 1250
  30. 1210 RN$ = RN$ +"XC":X = X -90
  31. 1250  IF X <50  THEN 1275
  32. 1260 RN$ = RN$ +"L":X = X -50
  33. 1275  IF X <40  THEN 1300
  34. 1280 RN$ = RN$ +"XL":X = X -40
  35. 1300  IF X <10  THEN 1350
  36. 1310 Y =  INT(X/10)
  37. 1320  FOR I = 1 TO Y
  38. 1330 RN$ = RN$ +"X":X = X -10: NEXT I
  39. 1350  IF X <9  THEN 1370
  40. 1360 RN$ = RN$ +"IX":X = X -9
  41. 1370  IF X <5  THEN 1400
  42. 1380 RN$ = RN$ +"V":X = X -5
  43. 1400  IF X <4  THEN 1430
  44. 1410 RN$ = RN$ +"IV":X = X -4
  45. 1430  IF X = 0  THEN 1450
  46. 1440 Y = X: FOR I = 1 TO Y:RN$ = RN$ +"I":X = X -1: NEXT I
  47. 1450  PRINT RN$,
  48. 1455 RN$ = ""
  49. 1460  NEXT Z
  50. 1470  PR# 0
  51. 1480  PRINT : PRINT "END": END